Kyber Networkハンズオン 後半 Part.1

こんにちは、びっとぶりっとです。

Kyber Networkハンズオン 前編 にてKyber Network自体の説明をしました。

2回目である今回は、Kyber Networkのハンズオンで作ったコントラクトの説明です。

コントラクトの要件

Kyber Networkを利用したバウンティプログラム用のスマートコントラクトを作ります。
このスマートコントラクトは下記の図の要領の通りバウンティプログラムのオーナーが所有するAddress Aからテスト用DAIで賞金を供出し、
バウンティ獲得者が所有するAddress Bにテスト用DAIをテスト用ETHに変えて送ることとします。

----------2019-01-31-15.36.28.png

コントラクトを実際に動かしてみる

前提

ソースコードの用意

$git clone git@github.com:KyberNetwork/workshop.git
$cd workshop
$touch contracts/BountyProgram.sol
$remixd -s ./contracts --remix-ide https://remix.ethereum.org

RemixでEthereumスマートコントラクト開発環境構築で説明した通りRemixをブラウザで表示して、ブラウザから contracts ディレクトリへアクセスできるようにします。

生成された BountyProgram.sol に以下のバウンティプログラムのソースコードをコピー&ペーストします。

バウンティプログラムのソースコード

pragma solidity ^0.4.23;
import "./ERC20Interface.sol";
import "./KyberNetworkProxy.sol";

contract KyberBountyWrapper {
    KyberNetworkProxy public kyberNetworkProxyInstance;
    SimpleBountyInterface public bountyInstance;
    ERC20 constant internal ETH_TOKEN_ADDRESS = ERC20(0x00eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee);

    constructor(KyberNetworkProxy _kyberNetworkProxyInstance, SimpleBountyInterface _bountyInstance) {
        bountyInstance = _bountyInstance;
        kyberNetworkProxyInstance = _kyberNetworkProxyInstance;
    }

    function() public payable { }

    function addReward(address _bountyAddress, ERC20 token, uint tokenQty) public {
        // 交換レートを取得
        uint minRate;
        (, minRate) = kyberNetworkProxyInstance.getExpectedRate(token, ETH_TOKEN_ADDRESS, tokenQty);

        // tokenQtyで指定した数量のトークン所有権をトークン送り元からこのコントラクトにする
        require(token.transferFrom(msg.sender, this, tokenQty));

        // フロントランニング攻撃防止のためにKyberにアクセス許可するトークン量を一旦0にする
        require(token.approve(kyberNetworkProxyInstance, 0));

        // Kyberにアクセス許可するトークン量をtokenQtyで指定した量にする
        token.approve(address(kyberNetworkProxyInstance), tokenQty);

        // tokenQtyで指定した量のトークンをminRateで指定するレートでETHに交換する
        uint destAmount = kyberNetworkProxyInstance.swapTokenToEther(token, tokenQty, minRate);

        // 交換された量のETHをRewardに追加する
        bountyInstance.addReward.value(destAmount)(_bountyAddress);
    }
}



library SafeMath {

  /**
  * @dev Multiplies two numbers, reverts on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
    // benefit is lost if 'b' is also tested.
    // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
    if (a == 0) {
      return 0;
    }

    uint256 c = a * b;
    require(c / a == b);

    return c;
  }

  /**
  * @dev Integer division of two numbers truncating the quotient, reverts on division by zero.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b > 0); // Solidity only automatically asserts when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold

    return c;
  }

  /**
  * @dev Subtracts two numbers, reverts on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b <= a);
    uint256 c = a - b;

    return c;
  }

  /**
  * @dev Adds two numbers, reverts on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    require(c >= a);

    return c;
  }

  /**
  * @dev Divides two numbers and returns the remainder (unsigned integer modulo),
  * reverts when dividing by zero.
  */
  function mod(uint256 a, uint256 b) internal pure returns (uint256) {
    require(b != 0);
    return a % b;
  }
}

interface SimpleBountyInterface {

    function createBounty(address _owner, string _task) public payable;
    function updateTask(address _bountyAddress, string _task) public;
    function addReward(address _bountyAddress) public payable;
    function addWinner(address _bountyAddress, address _winner) public;
    function removeWinner(address _bountyAddress, address _addressToRemove) public;
    function claimReward(address _bountyAddress, uint _amt, address _destAddress) public;
    function completeBounty(address _bountyAddress) public;
    function isWinner(address _bountyAddress, address _winner) public view returns (bool);
    function getTask(address _bountyAddress) public view returns (string);
    function getRewardAmount(address _bountyAddress) public view returns (uint);

}

contract BountyProgram is SimpleBountyInterface {

    using SafeMath for uint;

    struct Bounty {
        string task;
        uint reward;
        mapping(address=>bool) winners;
        address owner;
        address creator;
    }

    modifier bountyExists(address _bountyAddress) {
        require(exists[_bountyAddress]);
        _;
    }

    modifier onlyOwner(address _bountyAddress) {
        require(msg.sender == bounties[_bountyAddress].owner || msg.sender == bounties[_bountyAddress].creator);
        _;
    }

    mapping(address=>Bounty) public bounties; // For simplicity sake, every address can only have 1 bounty.
    mapping(address=>bool) public completed;
    mapping(address=>bool) public exists;

    function createBounty(address _owner, string _task) public payable {
        if(exists[_owner]) {
            require(completed[_owner]);
            bounties[_owner] = Bounty({task: _task, reward: msg.value, owner: _owner, creator: msg.sender});
            completed[_owner] = false;
        } else {
            exists[_owner] = true;
            bounties[_owner] = Bounty({task: _task, reward: msg.value, owner: _owner, creator: msg.sender});
        }
    }

    function updateTask(address _bountyAddress, string _task) public bountyExists(_bountyAddress) onlyOwner(_bountyAddress) {
        bounties[_bountyAddress].task = _task;
    }

    function addReward(address _bountyAddress) public payable bountyExists(_bountyAddress) {
        bounties[_bountyAddress].reward = bounties[_bountyAddress].reward.add(msg.value);
    }

    function addWinner(address _bountyAddress, address _winner) public bountyExists(_bountyAddress) onlyOwner(_bountyAddress) {
        bounties[_bountyAddress].winners[_winner] = true;
    }


    function removeWinner(address _bountyAddress, address _addressToRemove) public bountyExists(_bountyAddress) onlyOwner(_bountyAddress) {
        bounties[_bountyAddress].winners[_addressToRemove] = false;
    }

    function claimReward(address _bountyAddress, uint _amt, address _destAddress) public bountyExists(_bountyAddress) {
        require(bounties[_bountyAddress].winners[_destAddress]);
        require(bounties[_bountyAddress].reward >= _amt);
        bounties[_bountyAddress].reward = bounties[_bountyAddress].reward.sub(_amt);
        _destAddress.transfer(_amt);
    }

    function completeBounty(address _bountyAddress) public bountyExists(_bountyAddress) onlyOwner(_bountyAddress) {
        completed[_bountyAddress] = true;
    }

    function isWinner(address _bountyAddress, address _winner) public view bountyExists(_bountyAddress) returns (bool) {
        return bounties[_bountyAddress].winners[_winner];
    }

    function getTask(address _bountyAddress) public view bountyExists(_bountyAddress) returns (string) {
        return bounties[_bountyAddress].task;
    }

    function getRewardAmount(address _bountyAddress) public view bountyExists(_bountyAddress) returns (uint) {
        return bounties[_bountyAddress].reward;
    }

}

コントラクトのデプロイ

このバウンティプログラムを動かすために、以下の3つのコントラクトをデプロイする必要があります。

  • BountyProgram (バウンティプログラム本体)

特に留意点はないです。セットする値は特にないのでBountyProgramをRemixからデプロイします。

  • KyberBountyWrapper (バウンティプログラム本体にERC20トークンで賞金供出できるようにする)

_kyberNetworkProxyInstance にKyberNetworkProxyのコントラクトアドレスである 0x818E6FECD516Ecc3849DAf6845e3EC868087B755 をセットします。
_bountyInstance にBountyProgramのコントラクトアドレスを入力してデプロイします。BountyProgramのコントラクトアドレスは下図の赤枠のボタンを押すとコピーできますのでそれをそのままペーストします。

----------2019-01-31-18.28.42-1.png
  • ERC20 (KyberBountyWrapperに手持ちのERC20トークンの送金権を付与する)

ERC20のコントラクトはすでにデプロイされていて、実際にはデプロイするわけじゃなくてすでにデプロイされているコントラクトをRemixから使えるようにします。
At Address ボタンの右のフォームにDAIのコントラクトアドレスである 0xaD6D458402F60fD3Bd25163575031ACDce07538D を入力し At Address を押します。

----------2019-01-31-18.36.12.png

作ったコントラクトに手持ちのテストDAIの送金権を付与する

ERC20のコントラクトにある approve に以下を入力して transact ボタンを押します。
_spender にKyberBountyWrapperのコントラクトアドレスを入力します。KyberBountyWrapperのコントラクトアドレスは下図の赤枠のボタンを押すとコピーできますのでそれをそのままペーストします。
_value に10000000000000000000を入力します。DAIは18桁分は少数ですので、10DAIを表しています。もし手持ちが10DAIもないようでしたら適宜この値を少なくしてください。

----------2019-01-31-18.57.06.png

バウンティを作成する

BountyProgramのコントラクトにある createBounty に以下を入力して transact ボタンを押します。
_owner に自分のウォレットのアドレスを入力します。下図の赤枠のボタンを押すとコピーできますのでそれをそのままペーストします。
_task 適用な文字列を入力します。なんでもよいです。

----------2019-01-31-18.38.40.png

バウンティに賞金を供出する

KyberBountyWrapperのコントラクトにある addReward に以下を入力して transact ボタンを押します。
_bountyAddres に自分のウォレットのアドレスを入力します。
token にDAIのコントラクトアドレスである 0xaD6D458402F60fD3Bd25163575031ACDce07538D を入力します。
tokenQty にERC20のコントラクトにある approve にセットした _value の値を入力します。

----------2019-02-01-10.34.26.png

バウンティ獲得者の登録

BountyProgramのコントラクトにある addWinner に以下を入力して transact ボタンを押します
_bountyAddres に自分のウォレットのアドレスを入力します。
_winner に自分のウォレットのアドレスを入力します。これが賞金獲得者のアドレスです。今回は簡単さのために賞金供出者と賞金獲得者が同じにしています。

----------2019-01-31-19.02.09.png

バウンティ賞金を送る

BountyProgramのコントラクトにある claimReward に以下を入力して transact ボタンを押します
_bountyAddres に自分のウォレットのアドレスを入力します。
_destAddress にBountyProgramのコントラクトにある addWinner にセットした _winner と同じ値を入力します。

----------2019-01-31-19.04.07.png

以上でDAIで賞金供出からETHで賞金受け取りまで完了です。次回はソースコードの解説をします。

expand_less